--------------------------------------------------------------
--------------------------------------------------------------
-- Clean up orphans across an instance
--------------------------------------------------------------
--------------------------------------------------------------
-- Steps this script takes:
--    - Create a temp table containing all of the orphans from 
--      every database except for partialy contained databases.
--    - Attempt to create any missing NT authenticated logins
--        - If there is a \ in the name attempt to create the 
--          login.
--        - If there is no \ in the name add the @domain 
--          variable to the name and attempt to create the 
--          login.
--    - If the create for the NT authenticated login fails
--      save the error in the error column.
--    - If there is no error in the error column then attempt
--      to associated the orphaned user with a login of the 
--      of the same name.
--    - If there is an error then save it to error column. 
--    
--    - Output
--      - Number of orphans fixed and number of orphans 
--		  remaining.
--      - A list of all orphans
--
-- There are some limitations on what this script can do.  If
-- for example the orphaned user has a different name from the
-- associated login there isn't much I can do.
--------------------------------------------------------------
--------------------------------------------------------------


-- If temp table exists drop it
IF Object_Id('tempdb..#Orphans') IS NOT NULL
	DROP TABLE #Orphans
GO

-- Create new temp table
CREATE TABLE #Orphans ([dbname] sysname, [username] sysname, 
	[type] char(1), [error] varchar(4000),
	PRIMARY KEY (dbname, username))

-- This is the name of the main domain connecting to the instance.
-- This will be used as a first pass attempt to create windows
-- logins for orphans of type U (windows user) or G (windows group)
-- that don't already have a domain in the name.
DECLARE @domain varchar(200)
SET @domain = 'MyDomainName'

--------------------------------------------------------------
-- Load temp table with a list of orphans from each database
---- If contained databases is an option skip any database
---- that has a containment other than 'none'.
--------------------------------------------------------------
DECLARE @sql nvarchar(4000)

SET @sql =
	'DECLARE DBList CURSOR				' + CHAR(13) + 
	'READ_ONLY							' + CHAR(13) + 
	'FOR SELECT name FROM sys.databases ' + CHAR(13) + 
	'	WHERE name NOT IN (''tempdb'')	' 

IF EXISTS (SELECT * FROM sys.all_columns WHERE name = 'containment' 
			AND object_id = object_id('master.sys.databases'))
	SET @sql = @sql + CHAR(13) + 
	'	  AND containment = 0			'  

EXEC sp_executesql @sql

DECLARE @dbname nvarchar(400)
OPEN DBList

FETCH NEXT FROM DBList INTO @dbname
WHILE (@@fetch_status <> -1)
BEGIN
	IF (@@fetch_status <> -2)
	BEGIN
		SET @sql = 	'USE '+quotename(@dbname)+';  ' + char(13) + 
			' INSERT INTO #Orphans  (dbname, username, type)' + char(13) +   
			' SELECT '+quotename(@dbname,'''')+' AS dbname, name, type ' + char(13) +
			' FROM sys.database_principals ' + char(13) + 
			'	WHERE sid NOT IN (SELECT sid FROM sys.server_principals) ' + char(13) + 
			'	AND type IN (''S'',''G'',''U'') ' + char(13) + 
			'	AND LEN(sid) > 5 ' + char(13) + 
			'	AND name <> ''dbo'' '
		
		EXEC sp_executesql @sql
	END
	FETCH NEXT FROM DBList INTO @dbname
END

CLOSE DBList
DEALLOCATE DBList

--------------------------------------------------------------
---- Try to create any missing windows users
--------------------------------------------------------------
DECLARE OrphanList CURSOR
READ_ONLY
FOR SELECT DISTINCT 
		CASE WHEN username LIKE '%\%' THEN username
			ELSE @domain + '\' + username END
	FROM #Orphans 
	WHERE type IN ('G','U')

DECLARE @username nvarchar(400)
OPEN OrphanList

FETCH NEXT FROM OrphanList INTO @username
WHILE (@@fetch_status <> -1)
BEGIN
	IF (@@fetch_status <> -2)
	BEGIN
		IF NOT EXISTS (SELECT 1 FROM sys.server_principals
							WHERE name = @username)
		BEGIN
			SET @sql = 'CREATE LOGIN ' + quotename(@username) + ' FROM WINDOWS '
			BEGIN TRY
				EXEC sp_executesql @sql
			END TRY
			BEGIN CATCH
				UPDATE #Orphans SET error = ERROR_MESSAGE()
				WHERE username = @username
			END CATCH
		END
	END
	FETCH NEXT FROM OrphanList INTO @username
END

CLOSE OrphanList
DEALLOCATE OrphanList

--------------------------------------------------------------
---- Try to fix the orphans
--------------------------------------------------------------
DECLARE OrphanList CURSOR
READ_ONLY
FOR SELECT DISTINCT dbname, username, [type]
	FROM #Orphans 
	WHERE error IS NULL

-- DECLARE @dbname nvarchar(400)
-- DECLARE @username nvarchar(400)
DECLARE @type char(1)
DECLARE @loginname nvarchar(400)
OPEN OrphanList

FETCH NEXT FROM OrphanList INTO @dbname, @username, @type
WHILE (@@fetch_status <> -1)
BEGIN
	IF (@@fetch_status <> -2)
	BEGIN
		IF @username NOT LIKE '%\%' AND @type IN ('U','G')
			SET @loginname = @domain + '\' + @username
		ELSE
			SET @loginname = @username

		IF NOT EXISTS (SELECT 1 FROM sys.server_principals
							WHERE [type] = @type
							  AND name = @loginname
						)
		BEGIN
			UPDATE #Orphans SET error = QUOTENAME(@loginname,'''') + ' does not have a  ' + 
					'corrisponding server principal. Either the database principal name does ' +
					'match the server principal name or the server principal needs to be created.'
				WHERE username = @username
		END
		ELSE
		BEGIN
			SET @sql = 'USE ' + quotename(@dbname) + '; ' + 
				'ALTER USER ' + quotename(@username) + ' WITH LOGIN = ' + quotename(@loginname)

			BEGIN TRY
				EXEC sp_executesql @sql
			END TRY
			BEGIN CATCH
				UPDATE #Orphans SET error = ERROR_MESSAGE()
				WHERE username = @username
				  AND dbname = @dbname
			END CATCH
			END
	END
	FETCH NEXT FROM OrphanList INTO @dbname, @username, @type
END

CLOSE OrphanList
DEALLOCATE OrphanList

SELECT SUM(CASE WHEN error IS NULL THEN 1 ELSE 0 END) AS OrphansCleanedup,
	SUM(CASE WHEN error IS NOT NULL THEN 1 ELSE 0 END) AS RemainingOrphans
FROM #Orphans

SELECT * FROM #Orphans 
ORDER BY [dbname], CASE WHEN [error] IS NULL THEN 1 ELSE 0 END, [username]

Query->Include Client Statistics or Shft-Alt-S

Or hit this button on the tool bar

Note: This only turns Client Statistics on for the current query window.

Given that I’m lumping it with the SET STATISTICS commands it should be fairly obvious that it returns statistical information useful for tuning a query.

Specifically it returns

Query Statistics
When the execution occurred, the number of rows affected by a write (UPDATE, INSERT, DELETE) and the number of rows affected by a read (SELECT) and the number of statements for each and the total number of transactions.

Network Statistics
Number of server roundtrips and the number of packets and bytes, sent and received.

Time Statistics
Client processing time, total time and wait time on server replies. Note that is not the same as the wait time in say sys.dm_exec_requests. This is how long the client was waiting on a response from the server.

I’m sure you will agree that is fairly useful information, but it gets so much better.

Each time you run a query it adds a new column of statistics. Well, technically not a query but the entire execution even if it’s multiple batches. As I’m sure you expect there is a limit to the number of columns that it can display. After 10 executions they start rolling off the end so you only get the most recent 10 executions. But that’s still pretty helpful when trying to tune a query. Particularly given that each execution displays what has increased or decreased since the last execution and there is a column with the averages at the end.

Obviously this isn’t enough information to do anything with on its own but when combined with the STATISTICS queries and the query plan this can give you a nice history of what you’ve been up to.

• UserA is a member of Group1, Group2 and Group3.
• Group1 is set up as a server principal with a default database of DB1
• Group2 is set up as a server principal with a default database of DB2
• Group3 is set up as a server principal with a default database of DB3

 
When UserA logs into the instance what database is he connected to?

If you haven’t already guessed, my last two posts have been setup for this one. If you are unsure what NET USER and NET LOCALGROUP are read Adding new user and groups in windows and if you are unsure what I mean by a default database read Default Databases.

Now that we are all on the same page let’s figure this out.

First step is to create the user, all of the groups and add the user to each of them. In a command shell run as administrator run the following script.

NET USER "UserA" "NewPassword" /ADD
NET LOCALGROUP "Group1" /ADD
NET LOCALGROUP "Group2" /ADD
NET LOCALGROUP "Group3" /ADD
NET LOCALGROUP "Group1" "UserA" /ADD
NET LOCALGROUP "Group2" "UserA" /ADD
NET LOCALGROUP "Group3" "UserA" /ADD

Now we run some tests. The first thing I did was to open a copy of SSMS as UserA. To do this hold the shift key down while right clicking on the shortcut.

Then select Run as different user.

Log in as UserA and you now have a copy of SSMS using our test user. The extra work is necessary because you can’t just enter a username and password for a windows connection. Meanwhile our main user can open up another copy of SSMS. (I’m assuming this user will be a sysadmin and can make the changes needed.)

Test 1: Will a login associated with the user will override those associated with the group.

Run this code on the instance of your choice as a sysadmin (or securityadmin will work too).

CREATE LOGIN [yourdomain\Group1] FROM WINDOWS WITH DEFAULT_DATABASE = YourDB1
CREATE LOGIN [yourdomain\Group2] FROM WINDOWS WITH DEFAULT_DATABASE = YourDB2
CREATE LOGIN [yourdomain\Group3] FROM WINDOWS WITH DEFAULT_DATABASE = YourDB3
CREATE LOGIN [yourdomain\UserA] FROM WINDOWS WITH DEFAULT_DATABASE = YourDB4

Now open a query window using the copy of SSMS opened under UserA. Your query will be opened under YourDB4. So that’s answer number 1. The DEFAULT_DATABASE of the user will override any groups. That’s to be expected but it’s always good to check.

Test 2: If I have all three groups as logins which database do I end up in?

Now run this script using your sysadmin connection.

DROP LOGIN [yourdomain\Group1]

Now open a new query window using the copy of SSMS opened under UserA. The result is going to depend on what databases you set as the defaults. In my case it was always first database in alphabetical order by database name.

I want to put in a couple of caveats here. I ran this experiment several times in several ways to make sure it wasn’t database id, sid, or something like that. I also ran it using AD (active directory) groups and users rather than local windows groups and users. Every time it came up the same way. The first database in alphabetical order. All that being said there could be other factors that I missed. I certainly didn’t test layered groups. Where UserA belongs to Group1, Group1 belongs to Group2 etc. Also I’m told that there may be different priorities in AD groups and there are certainly different types of AD groups and users.

So there you go. Given multiple groups with different default databases it will be the first database in alphabetical order.

Probably :)

-- Creating a login with a default database
CREATE LOGIN [Domain\NewUser] FROM WINDOWS 
	WITH DEFAULT_DATABASE = TestDB
-- Change the default database of an existing login
ALTER LOGIN [Domain\NewUser] 
	WITH DEFAULT_DATABASE = NewDefaultDB

 
Default
The default default database (say that 5 times fast) is of course master.
 
Where?
You can find the default database for each server principal in the default_database_name column of sys.server_principals.

SELECT name, default_database_name 
FROM sys.server_principals

 
Problems
One of the most common problems I see with this is forgetting to create an associated database principal (user) for the default database. This will make it impossible to connect using that login without specifying a database it does have permissions to. The next most common issue I see is when a database has recently dropped but there are still server principals with default databases that point to it.
 
Why?
Typically the only real reason for a default database is convinence. In any connection string I’ve ever worked with you can specify a database to connect to and this overrides the default. That being said people frequently don’t specify a database to connect to. This can be an issue when dealing with applications like Access that will only let you work in the database that you initially connect to (at least as far as I can tell). This means that if the default database changes the connections in an Access database will no longer work.

Now I’m moving a little bit outside my normal comfort zone here. I’m not a windows guy. I’m a SQL guy. I did however manage to find just the commands I needed. And in the interest of documenting them for myself (that being one of the great benefits of blogging) here they are:

• Add a new user

  NET USER "NewUser" "NewPassword" /ADD

• Remove a user

  NET USER "NewUser" /DELETE

• List group membership of a user. Note: this also returns a lot of other information about the user.

  NET USER "NewUser"

• Add a new local windows group

  NET LOCALGROUP "NewGroup" /ADD

• Remove a local windows group

  NET LOCALGROUP "NewGroup" /DELETE

• Add a user to a local windows group

  NET LOCALGROUP "NewGroup" "NewUser" /ADD

• Remove a user from a local windows group

  NET LOCALGROUP "NewGroup" "NewUser" /DELETE

• List members of a local windows group

  NET LOCALGROUP "NewGroup"

If you just open a command shell and run these you will get the following error even if your user is a member of the admin group.

System error 5 has occurred.

Access is denied.

In order to avoid this error you need to run the command shell as administrator. If you hold down the shift key and right click on the shortcut you will get a much longer menu then you normally see. And near the top is the option Run as administrator.

Select that option and you will open the command shell in such a way that these commands will work. Of course this does assume that you are a member of the administrators group.

I’ll be honest, in the 20+ years of my career I’ve used extended properties maybe twice. But as I write this post I’m starting to rethink that in a very specific case. And I can think of several other cases where it would be highly useful.

• Put a TBD (to be deleted) date on “backup” objects.
  I discussed operational recovery a while back, and one of the things I mentioned was making copies of the old SP before you created a new one. Or creating a new version of a table with the current data before you do a major update. Well wouldn’t it be nice to put a TBD/date pair in the extended properties of those objects, and then have an automated process review them and actually delete them once that date has passed?
• Comments on schemas, tables or columns.
  Comments on SPs, functions etc are common and easy enough to do. They can let you know what changes have been made and why, what the purpose of the code is etc. Well with extended properties you can do the same thing with a table. You can add an extended property to let you know what the Delegate schema is for. Why has no one ever fixed the misspelling on the cheldrin table. Etc.
• Adding description and owner values for SQL Server logins
  This is the use case I was talking about earlier. If you work with legacy systems, network systems that have connections in from areas that don’t allow windows logins, etc then you probably have mixed authentication and SQL Server logins for various applications. If you are unlucky enough you might even have a SQL Server login called App_Id. Imagine having an extended property with the purpose of the account and the name of the team that requested it? The down side is that you can only use extended properties on database principals not server principals. So if your application id is going to be used on more than one database you should probably document it on each database that it’s used.

 
 
Example:

-- Create the Login and User
CREATE LOGIN MakeNotes WITH PASSWORD = 'T@st1'
GO
USE Test
GO
CREATE USER MakeNotes FROM LOGIN MakeNotes
GO

-- Add the extended properties by code
EXEC sys.sp_addextendedproperty @name=N'Description', @value=N'This user is for my example' , @level0type=N'USER',@level0name=N'MakeNotes'
GO
EXEC sys.sp_addextendedproperty @name=N'Owner', @value=N'DBA Team' , @level0type=N'USER',@level0name=N'MakeNotes'
GO

Add extended properties by GUI

-- View the extended properties
SELECT ep.*, dp.name FROM sys.extended_properties ep
JOIN sys.database_principals dp
	ON ep.major_id = dp.principal_id
WHERE class_desc = 'DATABASE_PRINCIPAL'
GO

Of the sessions I want to this particular weekend a number of them were performance tuning tips and I noticed one very common suggestion. In fact if you read blogs by experienced DBAs you will see the same thing over and over again. So what is this amazing tip that everyone seems to agree on?

Test first

Here’s the thing. If a setting worked best one way or the other every time then it wouldn’t be a setting would it? So before you make any changes, make sure you test first. The wider the change (instance setting vs query hint for example) the more careful you need to be. A lot of setting changes will only help occasionally or in fringe situations. Frequently you will find that the change you made that dramatically sped up one query dramatically slowed down multiple others.

You will occasionally find a setting that everyone pretty much agrees on. For example the setting cost threshold for parallelism. Almost everyone feels that it should be increased. Well, to be honest, everyone I’ve talked to thinks it should be increased. But you never know, there might be someone who disagrees. But now ask what it should be increased to. If you do some searching you can find a wide range of numbers and a lot of suggestions to, you guessed it, do some testing.

So what can you do? We took a three tiered approach.

1. First we keep enough licenses to cover the vast majority of our production instances. The high profile ones and the problem ones.
2. Then we added 2-3 additional floating licenses. We move these particular licenses around when we have an issue on a server. We don’t have the long term history but we can spotlight a server for a few days or weeks to get a feel for what’s going on.
3. Last but not least we have a light weight, home grown, monitoring system. This system is pretty simple and that’s by design. We aren’t trying to be perfect here, just better than nothing. Remember we have the professional system for anything really important.

 
In case anyone is interested we took an SSIS package that loops through a list of instances and used it to collect some information. Here is an example of one of the queries we use.

SELECT CAST(@@ServerName AS VarChar) AS Server_Name, 
	CAST(sysdatabases.name AS VarChar) AS Database_Name, CAST(sysdatabases.cmptlevel AS Int) CtmpLevel, 
	CAST(ISNULL(DatabasePropertyEx(sysdatabases.name,'Status'),'Removed') AS VarChar) AS Status,
	CAST(DatabasePropertyEx(sysdatabases.name,'Updateability') AS VarChar) AS Updateability,
	CAST(DatabasePropertyEx(sysdatabases.name,'UserAccess') AS VarChar) AS UserAccess,
	CAST(DatabasePropertyEx(sysdatabases.name,'Recovery') AS VarChar) AS Recovery,
	MAX(CASE WHEN type = 'D' THEN backup_finish_date ELSE NULL END) AS LastFull,
	MAX(CASE WHEN type = 'I' THEN backup_finish_date ELSE NULL END) AS LastDifferential,
	MAX(CASE WHEN type = 'L' THEN backup_finish_date ELSE NULL END) AS LastLog,
	-- I'm not worrying about the following types of backups although that could
	-- obviously be pulled just as easily.
	--	F = File or filegroup 
	--	G = Differential file 
	--	P = Partial 
	--	Q = Differential partial 
	SUSER_SNAME(sid) AS DBOwner
FROM master.dbo.sysdatabases sysdatabases
LEFT OUTER JOIN msdb.dbo.backupset backupset 
	ON backupset.database_name = sysdatabases.name
--		AND server_name = ?
WHERE sysdatabases.name <> 'tempdb'
GROUP BY sysdatabases.name, sysdatabases.cmptlevel, 
	DatabasePropertyEx(sysdatabases.name,'Status'),
	DatabasePropertyEx(sysdatabases.name,'Updateability'),
	DatabasePropertyEx(sysdatabases.name,'UserAccess'),
	DatabasePropertyEx(sysdatabases.name,'Recovery'),
	SUSER_SNAME(sid)

This returns a list of databases on the instance, some various settings and when the most recent backups were taken. We can then report on this information across all instances. This means that we get a single report with either an all clear, or a list of problems. Some of the reports we have include lists of any DBs that are marked READ_ONLY, RESTRICTED, OFFLINE, have no valid owner, have no FULL backup in the last day or week (depending on the backup schedule), no log backup in the last 12 hours (again depending on the schedule), etc. Some of the reporting can get a bit complicated and we collect quite a bit more information than this but this does give you a general overview of what’s we are doing. It takes a bit of effort to set up and build your report but it’s highly worth it. I think I spent about a month building the current system and it’s probably saved me 10 times that much over the last few years.

Thanks to Cathrine Wilhelmsen (b/t) for hosting this months T-SQL Tuesday with a subject of Monitoring!

Some of this also comes from previous conversations/reading about presentation best practices. And in the interest of completeness I’ve also gone through a few of Grant Fritchey’s (b/t) Speaker of the Month series for an additional point of view.

• Having a summary and or course objectives at the beginning is a good way to start the presentation but make sure you follow it.
• Follow up with a review at the end. If you don’t have time it can always be cut.
• Use Zoomit, large font, something. Demos aren’t nearly as much fun if I can’t read what you have typed from the middle of a small room.
  • Using both appeared to work the best. Large fonts let me follow along generally, Zoomit for emphasis or for GUI stuff that doesn’t have the larger font.
• Having a video of a demo play in the background while you talk is pretty cool. Maybe not the whole time (although I’ve seen that done too) but for a short period of time it can be a great emphasis to what you are talking about.
• Demos (even if you are going to type them in) should be smooth. Problems happen but minimize them.
  • I’m not going to go so far as don’t ever type. Sometimes the typing is part of the demo itself (intellisense), however don’t type if you don’t have to.
  • Some demo’s don’t have a lot of typing in them (GUIs) but if so they should well practiced so you can run them smoothly.
• If you have a demo that runs a long time have something else to do while you wait.
• I’m going to go against popular practice here and say I like slides with more information on them. Don’t read the slides. But next week when I’m looking at the slides I want them to mean something.
• That doesn’t mean the slides should be busy. Simple is better.
• BIG font for main points, small fonts for stuff for everyone to read later.
• If you can make them laugh while giving information it’s a plus.
  • Don’t go overboard though. If all they are doing is laughing they probably aren’t learning anything.
• No question or comment is bad but learn how to deflect questions/comments that run long/don’t pertain to your presentation.
• Use a mike or speak up. People came to the session to hear you speak. It would be a shame if they couldn’t.
• Repeat questions. It can be hard for everyone in the room to hear. Remember you have the mike.
• When answering questions “I don’t know” is ok. But “Great question. I don’t know the answer to that right now but I’ll figure it out and blog/post about it later” is better.
• If you have a small group that just means you can be more interactive.
• Presentation remotes/laser pointers are nice, they let you walk around while giving your presentation.
• If you can arrange to have someone who knows the subject really well show up in your session it can be fun. It’s also nice if someone asks a question that stumps you. They may be able to answer the question for you.
• Be Excited! It’s fun to watch someone be excited about a subject.
• Prizes are popular even if it’s just candy.

 
 
I’d love to hear your opinions on this list. If you are a presenter I’d like to hear what you feel works and what doesn’t. And presenter or not what would you like to see in a presenter?

I’m going to do an example of tracking jobs that haven’t run yet even though they are scheduled to. First thing we need is to build our own schedule table. This would be fairly tricky if we were actually scheduling our jobs on this table but our task is somewhat simpler than that. So what we are going to do is create a table with the last scheduled run date, next scheduled run date, last run start and stop datetimes, and frequency. Each time a job runs it will update it’s LastRunStart and LastRunEnd values as the first and last step. Then when our monitor job runs it can check if the NextSchRunDate is both greater than the LastRunStart (hasn’t run yet) and less than the current date/time (should have run by now). Next it will update the Last & NextSchRunDate for those jobs where the NextSchRunDate is past. Unfortunately this is only going to handle simple schedules. Once a week, once a day, every other day, every four hours etc. It will not be able to easily handle a schedule like “Mondays and Thursdays”. For something like that you would need two entries and more complicated code in your job to update the correct row in the schedule table.

CREATE TABLE MySchedule (
	JobId INT NOT NULL IDENTITY (1,1),
	JobName VARCHAR(255),
	IsActive BIT,
	FrequencyType CHAR(2), 
	FrequencyAmt INT,
	LastSchRunDate DATETIME,
	NextSchRunDate DATETIME,
	LastRunStart DATETIME,
	LastRunEnd DATETIME
	)

-- Sample data
INSERT INTO MySchedule VALUES 
	('Job runs every Monday', 1, 'wk', 1, '4/20/2015',
	'4/27/2015', NULL, NULL)

INSERT INTO MySchedule VALUES 
	('Job runs the 3rd of each month', 1, 'mm', 1, '4/03/2015', 
	'5/03/2015', NULL, NULL)

INSERT INTO MySchedule VALUES 
	('Job runs every 4 hours', 1, 'hh', 4, '4/25/2015', 
	'4/25/2015 04:00:00', NULL, NULL)

CREATE PROCEDURE MonitorJobs AS

	-- Report on late jobs
	-- Maybe generate a table and use DBMail to send it out.
	SELECT JobName, NextSchRunDate, LastRunStart
	FROM MySchedule
	WHERE IsActive = 1
	  AND NextSchRunDate < GETDATE()
	  AND (LastRunStart IS NULL
		OR NextSchRunDate > LastRunStart
		  )

	-- Update NextSchRunDate if the current report has been run.
	--
	-- Unfortunately you can't have a frequency type stored in a 
	-- column or variable so this has to be a bit of a hack.  I 
	-- could either do this as a cursor & dynamic SQL updating
	-- each row one at a time or a big case statement for each 
	-- frequency type.
	--
	-- The next difficulty is if both the last run and last schedule
	-- run were more than one frequency type * frequency amount ago.
	-- In order to get the "next" scheduled time we divide then multiply
	-- by the FrequencyAmt to remove the remainder.  This only works
	-- because all of the values are integers.
	--  
	UPDATE MySchedule 
	SET LastSchRunDate = NextSchRunDate,
		NextSchRunDate = 
			CASE WHEN UPPER(FrequencyType) IN ('YEAR','YY','YYYY') THEN
				DATEADD(YEAR, FrequencyAmt + DATEDIFF(YEAR, NextSchRunDate, GETDATE())
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)
				WHEN UPPER(FrequencyType) IN ('QUARTER','QQ','Q') THEN
				DATEADD(QUARTER, FrequencyAmt + DATEDIFF(QUARTER, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('MONTH','MM','M') THEN
				DATEADD(MONTH, FrequencyAmt + DATEDIFF(MONTH, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('DAYOFYEAR','DY','Y') THEN
				DATEADD(DAYOFYEAR, FrequencyAmt + DATEDIFF(DAYOFYEAR, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('DAY','DD','D') THEN
				DATEADD(DAY, FrequencyAmt + DATEDIFF(DAY, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('WEEK','WK','WW') THEN
				DATEADD(WEEK, FrequencyAmt + DATEDIFF(WEEK, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('WEEKDAY','DW','W') THEN
				DATEADD(WEEKDAY, FrequencyAmt + DATEDIFF(WEEKDAY, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('HOUR','HH') THEN
				DATEADD(HOUR, FrequencyAmt + DATEDIFF(HOUR, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('MINUTE','MI','N') THEN
				DATEADD(MINUTE, FrequencyAmt + DATEDIFF(MINUTE, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('SECOND','SS','S') THEN
				DATEADD(SECOND, FrequencyAmt + DATEDIFF(SECOND, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
				WHEN UPPER(FrequencyType) IN ('MILLISECOND','MS') THEN
				DATEADD(MILLISECOND, FrequencyAmt + DATEDIFF(MILLISECOND, NextSchRunDate, GETDATE()) 
					/ FrequencyAmt * FrequencyAmt, 
					NextSchRunDate)	
			END
	WHERE IsActive = 1
	  AND NextSchRunDate < GETDATE()
	  AND NextSchRunDate < LastRunStart

Now obviously this is fairly limited. It does however give a good starting place. For example if you need a history it wouldn’t be hard to modify the code to do inserts rather than updates. Or if you want long running jobs add an expected run time column and if the job has a start time but not an end time and the difference between the start time and now is longer than the expected time you send an alert.